Macro Tips

This is a macro that displays the latest version of each Atlassian product.

1. Select the Create Macro button on the Macro page.
2. Select Custom Script Macro.
3. Set the following fields:
   • Key: atl-versions
   • Name: Atlassian Versions
   • Description: Displays the latest version of each Atlassian product
   • Body Type: None
   • Output Type: Block
4. Skip the +Parameter section.
5. Enter the following code in the Macro Code field:
   Copy script

   1

   2

   3

   4

   5

   6

   7

   8

   9

   10

   11

   12

   13

   14

   15

   16

   17

   18

   19

   20

   21

   22

   23

   24

   25

   26

   27

   28

   29

   30

   31

   32

   33

   34

   35

   36

   37

   38

   39

   40

   import com.atlassian.confluence.xhtml.api.XhtmlContent
   import com.atlassian.sal.api.component.ComponentLocator
   import groovy.xml.MarkupBuilder
   import groovyx.net.http.ContentType
   import groovyx.net.http.HTTPBuilder
   import groovyx.net.http.Method
   
   def httpBuilder = new HTTPBuilder("https://marketplace.atlassian.com")
   def xhtmlContent = ComponentLocator.getComponent(XhtmlContent)
   
   def rt = httpBuilder.request(Method.GET, ContentType.JSON) {
       uri.path = "/rest/1.0/applications"
   }
   
   List<Map> apps = rt.applications
   
   def writer = new StringWriter()
   def builder = new MarkupBuilder(writer)
   
   builder.table {
       tbody {
           tr {
               th { p("App") }
               th { p("Latest version") }
           }
   
           apps.sort { it.order }.each { app ->
               rt = httpBuilder.request(Method.GET, ContentType.JSON) {
                   uri.path = "/rest/1.0/applications/${app.key}"
               }
   
               tr {
                   td { p(app.name) }
                   td { p(rt.versions.isEmpty() ? "No Versions Found" : rt.versions.first().version) }
               }
           }
       }
   }
   
   xhtmlContent.convertStorageToView(writer.toString(), context)

6. Skip the Macro Javascript Code, Macro CSS Style fields.
7. Tick the Lazy Loaded checkbox.
8. Click Add.
9. You can see your new macro when the Macro page loads.